Maple

[Gjest]

Er det noen som vet om det er publisert en bra innføring i Maple på norsk?
Jeg vil egentlig ikke kunne mer enn å skrive inn funksjoner og se hvordan de ser ut, med en og flere variable.

[Bernoulli]

Du trenger ikke se på noen publisert innføring for det. Jeg kan skrive noen eksempler.

Du vil plotte f(x) = x^2 i intervallet (-2,2)

Kode: Velg alt

plot(x^2 , x = -2..2);

Eller så kan du først definere funksjonen f. Dette kan du gjøre på minst to forskjellige måter:

Kode: Velg alt

f := (x) -> x^2; 
plot(f(x), x=-2..2);

eller

Kode: Velg alt

f := unapply(x^2 , x);
plot(f(x), x=-2..2);

Hvis du feks skal plotte tan(x) i intervallet (-2 [symbol:pi] , 2 [symbol:pi]) vil du se at y-aksen på figuren blir altfor stor. Dette løser du ved å slenge på en y = a..b, feks

Kode: Velg alt

plot(tan(x) , x = -2*Pi..2*Pi , y = -5..5);

Å definere funsksjoner med flere variable fungerer på samme måte, feks

Kode: Velg alt

f := (x,y,z) -> x^2 + y^2 + z^2;

eller

Kode: Velg alt

f := unapply(x^2 + y^2 + z^2 , x,y,z);

For å plotte en funksjon med to variable, bruker du plot3d:

Kode: Velg alt

plot3d(x^2+y^2 , x=-1..1 , y=-1..1);

Det finnes også mange andre plottefunksjoner. Feks kan du lage en liten animasjon:

Kode: Velg alt

with(plots);
animate(plot , [b + x , x=-2..2] , b = -1..1);

Kanskje jeg kan fylle på med mer senere. Ellers kan du bruke hjelpefunskjonen i maple.

[Gjest]

Så fint, nå får jeg til å plotte enkle saker. Takker.

Har et område jeg har vansker med å tegne på arket, det er følgende:
The region in the first octant of 3-space that has finite volume and is bounded by the surfaces x=0, z=0, x+y=1 og z=y[sup]2[/sup].

Er det en grei sak å fremstille i Maple?

[Bernoulli]

Jeg vet ikke om det er noen veldig enkle måter å gjøre dette på, unntatt å plotte hver side for seg. Noe jeg bruker ofte er å legge flere grafer inn i samme vindu (for å sammenligne). Da kan du feks bruke syntaxen

Kode: Velg alt

with(plots);
figur1 := plot(x , x=0..2):
figur2 := plot(x^2 , x=0..2, color = black):
plots[display](figur1, figur2);

Merk at jeg lar den ene få en annen farge, og avslutter plottekommandoene med en : istedet for ;. Du kan selv prøve med en ; for å se hvorfor jeg gjør dette. Å gjøre dette i 3D fungerer på nøyaktig samme måte.

Feks på ditt problem har kan vi skrive

Kode: Velg alt

with(plots);
f := (x,y) -> y^2;
g := x -> 1-x;
figur1 := plot3d([x,y,y^2], x=0..1, y = 0..g(x)):
figur2 := plot3d([x,1-x,z], x=0..1, z = 0..f(0,1-x)):
plots[display](figur1, figur2);

Dersom du vil kan du legge til de to flatene i xy-planet og yz-planet, slik at det ser ut som et solid stykke.

Andre plottefunksjoner som kan være verdt en titt er
implicitplot
implicitplot3d
for å plotte implisitte uttrykk, feks kulen x^2+y^2+z^2 = 1.

For å plotte i polarkoordinater eller kulekoordinater bruker du feks

Kode: Velg alt

plot(1, theta=0..2*Pi, phi=0..Pi, coords = spherical)

Dvs vi bruker de samme kommandoene som tidligere, men vi spesifiserer hvilket koordinatsystem vi skal bruke.

[Gjest]

Takk for alt så langt, er ikke alt ovenfor jeg får til å funke i Maple, men.
Hva med når jeg vil se skjæringen mellom parabolidene z=10-x[sup]2[/sup]-y[sup]2[/sup] og z = 2(x[sup]2[/sup]+y[sup]2[/sup]-1)?

[Bernoulli]

Jeg har endret på en liten feil i koden over. Får du det til å funke nå da? Merk at dersom du skal bruke noen andre kommandoer enn bare plot og plot3d så bør / må du først skrive with(plots). Det holder at du gjør dette én gang i dokumentet ditt.

Så vidt jeg vet er det ikke noen enkle kommandoer for å plotte skjæringspunktene til to funksjoner. Du må bare være litt oppfinnsom og bruke det du allerede kan.

Feks kan du plotte begge funksjonene i samme vindu:

Kode: Velg alt

with(plots);
plots[display](
  plot3d(10-x^2-y^2,x=-3..3,y=-3..3) ,
  plot3d(2*(x^2+y^2-1),x=-3..3,y=-3..3)
);

Merk at jeg bruker litt annen notasjon enn jeg har brukt tidligere.

Du kan plotte xy-koordinatene til skjæringskurven:

Kode: Velg alt

f := (x,y)-> 10-x^2-y^2;
g := (x,y)-> 2*(x^2+y^2-1);
implicitplot(f(x,y)-g(x,y) = 0, x=-3..3,y=-3..3);

Dersom du må ha denne kurven i 3D kan du gjøre det på følgende tungvinne måte:

Kode: Velg alt

f := (x,y)-> 10-x^2-y^2;
g := (x,y)-> 2*(x^2+y^2-1);
losn := solve(f(x,y)-g(x,y) = 0, y);
sol1 := unapply(losn[1] , x);
sol2 := unapply(losn[2] , x);
plots[display](
   plot3d([x , sol1(x), f(x,sol1(x))], x=-3..3, y=-3..3) ,
   plot3d([x,sol2(x), f(x,sol2(x))], x=-3..3, y=-3..3), axes=normal
);

Dersom noen vet om en bedre måte å gjøre dette på kan de hversågod å si i fra.
Merk at jeg hele tiden skifter på notasjonen. Det finnes alltid flere måter å gjøre samme ting på

Vennligst fyr på med flere spørsmål. Jeg trenger å friske opp litt kunnskaper i Maple Kanskje jeg kan legge på litt bilder senere...

[Gjest]

Nå ble det, så utrolig tøft!
Det blir så mye lettere å se for seg diverse integral over figurer i rommet når man gjøre slikt.
Maple kan sikkert rekne ut det meste man ber det om. Burde lære meg å bruke det.

Takk igjen, veldig morsomt.

[Gjest]

Hva gjør jeg galt her?

with(plots);
plots[display](
  plot3d(2x + 2y,x=0..1,y=0..1) ,
  plot3d(x^2+y^2-1,x=0..1,y=0..1)
);

Gir feilmeldingen "Error, (in plots/display) first argument must be a plot structure or list, set or array of plot structures".

[Bernoulli]

Du må huske på gangetegnene: 2*x+2*y

Hvilken versom av maple bruker du egentlig? Jeg fikk feilmeldingen "Error, missing operator or `;`", og markøren flytter seg automatisk til der feilen er (ofte).

Du bør absolutt legge på aksene, feks rett før ");" legger du til axes=normal

[Gjest]

Maple 10.
Er noe rart, for hvis jeg f.eks. nå kopierer inn det jeg postet forleden, vil det ikke prøve å plottes, selv om det står på math, får bare ny linje. Må være noe fundamentalt jeg ikke har lært meg.